home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HamCall (October 1991)
/
HamCall (Whitehall Publishing)(1991).bin
/
bcast
/
bcstcble
/
coaxpwr.asc
< prev
next >
Wrap
Text File
|
1990-10-14
|
8KB
|
130 lines
10 REM *****************************************************
20 REM
30 REM COAX TRANSMISSION LINE PEAK AND AVERAGE POWER RATINGS
40 REM FOR AM AND FM FREQUENCIES
50 REM
60 REM BY STEVE SCHOTT
70 REM OCTOBER 3, 1981
80 REM
90 REM *****************************************************
100 REM ------------------------------------
110 REM TEMP FACTOR DATA FOR FOAM CABLE
120 REM 1/2", 7/8", & 1-5/8" FOAM AND 5" AIR
130 REM ------------------------------------
140 DATA 1.42, 1.39, 1.37, 1.33, 1.3, 1.27, 1.25, 1.23, 1.215, 1.2, 1.18
145 DATA 1.16, 1.14, 1.12, 1.09, 1.07, 1.05, 1.03, 1.115
150 DATA 1, .98, .95, .935, .92, .9, .88, .86, .84, .825, .81, .79, .77
155 DATA .75, .73, .7, .68, .665, .65, .635
160 DATA .62, .6, .58, .565, .55, .53, .51, .495, .48, .46, .44, .425
165 DATA .41, .39, .37, .355, .34, .33, .32, .29
170 DATA .27, .26, .25, .235, .22, .2, .18, .165, .15, .135, .12
180 REM --------------------------------------
190 REM TEMP FACTOR DATA FOR 3" & 4" AIR CABLE
200 REM --------------------------------------
210 DATA 1.29, 1.27, 1.25, 1.235, 1.22, 1.2, 1.18, 1.17, 1.16, 1.145
215 DATA 1.13, 1.11, 1.09, 1.07, 1.05, 1.04, 1.03, 1.15, .985
220 DATA .97, .955, .94, .925, .91, .895, .88, .865, .85, .84, .83
225 DATA .815, .8, .785, .77, .765, .75, .74, .73, .715
230 DATA .44, .43, .42, .405, .39, .38, .37, .36, .35, .335, .32
240 CL$ = " "
245 REM String of Blanks to Clear Line
250 D$ = CHR$(248) 'ASCII Degree Symbol
260 Q$ = CHR$(34) 'Quotation Mark (")
270 REM PITCH12$ = CHR$(27) + CHR$(31) + CHR$(11) 'Brother HR-35 Code
280 REM PITCH10$ = CHR$(27) + CHR$(31) + CHR$(13) 'Brother HR-35 Code
290 CLS
300 PRINT "═══════════════════════════════════════════════════════;"
310 PRINT ": D E - R A T I N G O F C O A X I A L C A B L E :"
320 PRINT "═══════════════════════════════════════════════════════:"
330 PRINT "Frequency: AM or FM (A/F)? "; : INPUT; FREQ$
340 IF FREQ$ = "a" OR FREQ$ = "A" THEN FREQ$ = "1 MHz" : M = 1.25 : GOTO 370
350 IF FREQ$ = "f" OR FREQ$ = "F" THEN FREQ$ = "100 MHz" : M = 0 : GOTO 370
360 GOTO 330
370 PRINT FREQ$
380 PRINT "Transmitter Power Output (in kW): "; : INPUT ; TPO$
390 TPO = VAL(TPO$) : IF TPO <= 0 THEN 380
400 TPO$ = TPO$ + " kW" : PRINT TPO$
410 PRINT "Maximum Temperature (in "; D$; "F): "; : INPUT; TEMP$
420 TEMP = VAL(TEMP$) : IF TEMP <= 0 THEN 410
430 CENT% = (TEMP - 32) / 1.8
440 IF CENT% < 20 OR CENT% > 90 THEN PRINT "TEMP. OUT OF RANGE":GOTO 410
450 PRINT TEMP$; D$; "F /"; STR$(CENT%); D$; "C"
470 PRINT "Minimum Line Pressure (in psi): "; : INPUT; PRESSURE$
480 PRESSURE% = VAL(PRESSURE$)
490 PFACTOR = 1 + (PRESSURE% * .012)
495 IF PRESSURE% < 0 OR PRESSURE% > 10 THEN 470
500 PRESSURE$ = PRESSURE$ + " psi" : PRINT PRESSURE$
510 PRINT "________________________________________________________"
520 PRINT "A. 7/8";Q$ : PRINT "E. 4";Q$
530 PRINT "B. 1-5/8";Q$ : PRINT "F. 4-1/16";Q$
540 PRINT "C. 3 or 3-1/8";Q$ : PRINT "G. 5";Q$
550 PRINT "D. 3-1/2";Q$ : PRINT "H. 6-1/8";Q$
560 PRINT "Select Coaxial Line Size: "; : INPUT ; A$
570 IF A$ = "a" OR A$ = "A" THEN F1 = .5 : RR = -19 : COAX$ = "7/8" + Q$ : PEAK$ = "44 kW" : AVERAGE$ = "Foam = 5.1 kW / Air = 6.4 kW" : GOTO 660
580 IF A$ = "b" OR A$ = "B" THEN F1 = .37 : RR = -19 : COAX$ = "1-5/8" + Q$ : PEAK$ = "145 kW" : AVERAGE$ = "Foam = 13.3 kW / Air = 14.4 kW" : GOTO 660
590 IF A$ = "C" THEN F1 = .34 : RR = 52 : COAX$ = "3 or 3-1/8" + Q$:PEAK$="Flex = 320 kW / Rigid = 400 kW" : AVERAGE$ = "Flex = 37 kW / Rigid = 48kW":GOTO 660
600 IF A$ = "d" OR A$ = "D" THEN F1 = .32 : RR = 52 : COAX$ = "3-1/2" + Q$ : PEAK$ = "940 kW" : AVERAGE$ = "48 kW" : GOTO 660
610 IF A$ = "e" OR A$ = "E" THEN F1 = .3 : RR = 52 : COAX$ = "4" + Q$ : PEAK$ = "490 kW" : AVERAGE$ = "56 kW" : GOTO 660
620 IF A$ = "f" OR A$ = "F" THEN F1 = .3 : RR = 52 : COAX$ = "4-1/16" + Q$ : PEAK$ = "1200 kW" : AVERAGE$ = "92 kW" : GOTO 660
630 IF A$ = "g" OR A$ = "G" THEN F1 = .3 : RR = -19 : COAX$ = "5" + Q$ : PEAK$ = "790 kW" : AVERAGE$ = "73 kW" : GOTO 660
640 IF A$ = "h" OR A$ = "H" THEN F1 = .3 : RR = 52 : COAX$ = "6-1/8" + Q$ : PEAK$ = "2600 kW" : AVERAGE$ = "210 kW" : GOTO 660
650 GOTO 560
660 FOR I = 17 TO 20 : PRINT : NEXT I
670 PRINT COAX$; " Line"
680 PRINT "* * * PLEASE WAIT * * *"
690 FOR R = 1 TO CENT% + RR : READ TFACTOR : NEXT R
700 RESTORE
710 PRINT CL$ : PRINT "IS THIS DATA CORRECT (Y/N)? "; : INPUT ; A$
720 IF A$ = "n" OR A$ = "N" THEN GOTO 290
730 GOSUB 740 : GOTO 970
740 CLS
750 PRINT PITCH12$; TAB(12)"================================================="
760 L$ = " EQUIVALENT POWER IN " + COAX$ + " COAX WITH " + TPO$
770 PRINT TAB(38 - (LEN(L$)/2)) L$
780 PRINT TAB(12)"-------------------------------------------------"
790 PRINT TAB(12)" Line Size: ";COAX$; TAB(48)"(FACTOR = "; : PRINT USING "#.###)";F1
800 PRINT TAB(12)" Temperature: ";TEMP$; D$; "F /"; STR$(CENT%); D$; "C"; TAB(48)"(FACTOR = "; : PRINT USING "#.###)";TFACTOR
810 PRINT TAB(12)" Pressure: ";PRESSURE$; TAB(48)"(FACTOR = "; : PRINT USING "#.###)";PFACTOR
820 PRINT TAB(12)"================================================="
830 PRINT TAB(15)"--VSWR--"; TAB(34)"--AVERAGE--"; TAB(55)"--PEAK--"
840 FOR VSWR = 1 TO 2.1 STEP .1
850 V = VSWR^2
860 A1 = TPO * ((V + 1) + F1 * (V - 1))
870 A2 = TFACTOR * PFACTOR * 1 * 2 * VSWR
880 AVERAGE = A1 / A2
890 PEAK = TPO * ((1 + M)^2) * VSWR
900 PRINT TAB(15); : PRINT USING "#.# to 1";VSWR; : PRINT TAB(35); : PRINT USING "###.# kW";AVERAGE; : PRINT TAB(55); : PRINT USING "###.# kW";PEAK
910 NEXT VSWR
920 PRINT TAB(12)"================================================="
930 PRINT TAB(12)" MAX RATING Average: ";AVERAGE$
940 PRINT TAB(12)" AT ";FREQ$; TAB(29)"Peak: ";PEAK$
950 PRINT TAB(12)"================================================="
960 RETURN
970 PRINT "N";: PRINT "EW DATA - ";: PRINT "P";: PRINT "RINT DATA - ";: PRINT "Q"; : PRINT "UIT";: A$ = INPUT$(1)
980 IF A$ = "q" OR A$ = "Q" THEN END
990 IF A$ = "n" OR A$ = "N" THEN GOTO 290
1000 IF A$ = "p" OR A$ = "P" THEN D$ = "`" : GOSUB 1750 : LPRINT PITCH10$ : D$ = CHR$(248) : GOTO 970
1010 GOTO 970
1750 LPRINT PITCH12$; TAB(12)"==============================================="
1760 L$ = " EQUIVALENT POWER IN " + COAX$ + " COAX WITH " + TPO$
1770 LPRINT TAB(38 - (LEN(L$)/2)) L$
1780 LPRINT TAB(12)"-----------------------------------------------"
1790 LPRINT TAB(12)" Line Size: ";COAX$; TAB(48)"(FACTOR = "; : LPRINT USING "#.###)";F1
1800 LPRINT TAB(12)" Temperature: ";TEMP$; D$; "F /"; STR$(CENT%); D$; "C"; TAB(48)"(FACTOR = "; : LPRINT USING "#.###)";TFACTOR
1810 LPRINT TAB(12)" Pressure: ";PRESSURE$; TAB(48)"(FACTOR = "; : LPRINT USING "#.###)";PFACTOR
1820 LPRINT TAB(12)"==============================================="
1830 LPRINT TAB(15)"--VSWR--"; TAB(34)"--AVERAGE--"; TAB(55)"--PEAK--"
1840 FOR VSWR = 1 TO 2.1 STEP .1
1850 V = VSWR^2
1860 A1 = TPO * ((V + 1) + F1 * (V - 1))
1870 A2 = TFACTOR * PFACTOR * 1 * 2 * VSWR
1880 AVERAGE = A1 / A2
1890 PEAK = TPO * ((1 + M)^2) * VSWR
1900 LPRINT TAB(15); : LPRINT USING "#.# to 1";VSWR; : LPRINT TAB(35); : LPRINT USING "###.# kW";AVERAGE; : LPRINT TAB(55); : LPRINT USING "###.# kW";PEAK
1910 NEXT VSWR
1920 LPRINT TAB(12)"==============================================="
1930 LPRINT TAB(12)" MAX RATING Average: ";AVERAGE$
1940 LPRINT TAB(12)" AT ";FREQ$; TAB(29)"Peak: ";PEAK$
1950 LPRINT TAB(12)"==============================================="
1960 RETURN